Создание детали с несколькими типами и выпадающим списком на кнопке "Add" для BPM 7.5

EXEC [dbo].[tsp_RegisterPage]
             @ModuleEntityName = N'Activity', - название объекта (например, «Деталь»)
             @PageName = N'TaskPage', - название страницы редактирования (например, «E-mail»)
             @TypeColumnUId =  '00000000-0000-0000-0000-00000000000000', – UId колонки тип в объекте (UID находим через метаданные объекта по названию колонки (например, Type)
             @TypeValue = '00000000-0000-0000-0000-00000000000000', - Id типа задача (ID записи, например, E-mail)
             @AddMenuCaptionRus = 'Добавить задачу',
             @AddMenuCaptionEng = 'Add Task',
             @CardHeaderCaptionRus = 'Задача',
             @CardHeaderCaptionEng = 'Task'

USE [ter-test]
GO
/****** Object:  StoredProcedure [dbo].[tsp_RegisterPage]    Script Date: 6/2/2015 9:42:42 PM ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[tsp_RegisterPage] 
       @ModuleEntityName NVARCHAR(255),
       @PageName NVARCHAR(255),
       @TypeColumnUId NVARCHAR(255),
       @TypeValue NVARCHAR(255),
       @AddMenuCaptionRus NVARCHAR(255),
       @AddMenuCaptionEng NVARCHAR(255),
       @CardHeaderCaptionRus NVARCHAR(255),
       @CardHeaderCaptionEng NVARCHAR(255)
AS
BEGIN
       SET NOCOUNT ON;
 
       declare @SysModuleEntityId NVARCHAR(255);
       set @SysModuleEntityId = (select top 1 Id from SysModuleEntity where SysEntitySchemaUId = (select top 1 [UId] from SysSchema where Name = @ModuleEntityName))
 
       IF (@SysModuleEntityId IS NULL)
       BEGIN
       -- 1 Этап Создание записи SysModuleEntity
         INSERT into SysModuleEntity(SysEntitySchemaUId, TypeColumnUId) values((SELECT TOP 1 [UId] FROM SysSchema WHERE Name = @ModuleEntityName), @TypeColumnUId)  
       END
 
       -- 3 Этап Создание записи SysModuleEdit
       insert INTO SysModuleEdit
       (SysModuleEntityId,UseModuleDetails,CardSchemaUId, TypeColumnValue) VALUES
       ((SELECT Id from SysModuleEntity where SysEntitySchemaUId = (SELECT TOP 1 [UId] FROM SysSchema WHERE Name = @ModuleEntityName)),
       1,(select TOP 1 UId from SysSchema where Name = @PageName), @TypeValue)
 
       if (@AddMenuCaptionRus <> '')
       begin
             -- 7
             if (exists (select 1 from SysCulture where Id = '1A778E3F-0A8E-E111-84A3-00155D054C03'))
             begin
                    insert into SysModuleEditLcz (RecordId,ColumnUId,SysCultureId,Value)
                    values ((select Id from SysModule where Code = @ModuleEntityName),
                    'A19BF4BF-E22B-49B5-B6E0-918FF6290020', '1A778E3F-0A8E-E111-84A3-00155D054C03',       @AddMenuCaptionRus);
             end
             -- 8
             if (exists (select 1 from SysCulture where Id = 'A5420246-0A8E-E111-84A3-00155D054C03'))
             begin
             insert into SysModuleEditLcz (RecordId,ColumnUId,SysCultureId,Value)
                    values       ((select Id from SysModule where Code = @ModuleEntityName),
                    'A19BF4BF-E22B-49B5-B6E0-918FF6290020', 'A5420246-0A8E-E111-84A3-00155D054C03', @AddMenuCaptionEng);
             end
       end
 
 
       if (@CardHeaderCaptionRus <> '')
       begin
             -- 7
             if (exists (select 1 from SysCulture where Id = '1A778E3F-0A8E-E111-84A3-00155D054C03'))
             begin
                    insert into SysModuleEditLcz (RecordId,ColumnUId,SysCultureId,Value)
                    values ((select Id from SysModule where Code = @ModuleEntityName),
                    '55132174-2B96-4E0A-830C-B8E952B12C45', '1A778E3F-0A8E-E111-84A3-00155D054C03',       @CardHeaderCaptionRus);
             end
             -- 8
             if (exists (select 1 from SysCulture where Id = 'A5420246-0A8E-E111-84A3-00155D054C03'))
             begin
             insert into SysModuleEditLcz (RecordId,ColumnUId,SysCultureId,Value)
                    values       ((select Id from SysModule where Code = @ModuleEntityName),
                    '55132174-2B96-4E0A-830C-B8E952B12C45', 'A5420246-0A8E-E111-84A3-00155D054C03', @CardHeaderCaptionEng);
             end
       end
 
END

-- Версия то у нас английская, однако странновато выглядит. Ну да ладно, русскую локализацию я указывал, попадаём в IF.
IF (@CardHeaderCaptionRus <> '')
IF (@AddMenuCaptionRus <> '')

-- Эта строка смущает куда больше, т.к. в качестве @ModuleEntityName, как я понял, нужно указывавть имя объекта детали, а не раздела. И его не будет в колонке Code таблицы SysModule, там только объект разделов. Т.е. Record ID в SysModuleEditLcz будет NULL. И вообще, та ли эта таблица, куда должны записываться значения @AddMenuCaptionEng и @CardHeaderCaptionEng?
SELECT Id FROM SysModule WHERE Code = @ModuleEntityName

EXEC [dbo].[tsp_RegisterDetailPage]
@detailObjectName = 'UsrIssue' -- имя объекта, указанного при создании детали
,@typeColumnUid = '00000000-0000-0000-0000-000000000000' -- UId колонки объекта детали, отвечающей за тип, смотрим в метаданных
,@typeValue = '00000000-0000-0000-0000-000000000000' -- Значение одного из типов из таблицы, на которую ссылается колонка типа
,@pageNameForSpecificType = 'UsrUsrIssue1PageV2' -- имя страницы редактирования для @typeValue
,@itemPosition = 0 -- позиция элемента в выпадающем меню кнопки "Add" детали
,@actionKindCaption = 'Bug' -- Название пункта меню
,@actionKindName = 'Bug' -- Не знаю что, пусть будет
,@pageCaption = 'Bug' -- Заголовок страницы редактирования

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE PROCEDURE [dbo].[tsp_RegisterDetailPage]
	@detailObjectName nvarchar(255)
	,@typeColumnUid uniqueidentifier
	,@typeValue uniqueidentifier
	,@pageNameForSpecificType nvarchar(255)
	,@itemPosition int
	,@actionKindCaption nvarchar(255)
	,@actionKindName nvarchar(255)
	,@pageCaption nvarchar(255)
AS
BEGIN
	SET NOCOUNT ON;
 
	-- Step 1. Declare constants
	declare @cultureUnitedKindomId uniqueidentifier = 'A5420246-0A8E-E111-84A3-00155D054C03';
	declare @cultureUnitedStatesId uniqueidentifier = 'D294EECE-62E7-46DA-ACA3-381D2E825C7D';
	declare @pageCaptionElementId uniqueidentifier = '55132174-2B96-4E0A-830C-B8E952B12C45'; -- TODO: Know from which table and if correct.
	declare @actionKindCaptionElementId uniqueidentifier = 'A19BF4BF-E22B-49B5-B6E0-918FF6290020';
 
	-- Step 2. Initializing variables
	declare @currentDateTime datetime = GETDATE();
	declare @detailObjectUid uniqueidentifier = (select top 1 UId from SysSchema ss where ss.Name = @detailObjectName);
	declare @cardSchemaUId uniqueidentifier = (select top 1 UId from SysSchema where Name = @pageNameForSpecificType);
	declare @userId uniqueidentifier = (select top 1 CreatedById from SysSchema where [UId] = @detailObjectUid);
 
	-- Step 3. Getting SysModuleEntity Id and updating a record with @typeColumnUid
	declare @moduleEntityId uniqueidentifier = (select Id from SysModuleEntity sme where sme.SysEntitySchemaUId = @detailObjectUid);
	if (@moduleEntityId is null)
		begin
			insert into SysModuleEntity(SysEntitySchemaUId, TypeColumnUId) VALUES(@detailObjectUid, @TypeColumnUId);
			set @moduleEntityId = (select top 1 Id from SysModuleEntity where SysEntitySchemaUId = @detailObjectUid);
		end
	else
		update SysModuleEntity set TypeColumnUId = @typeColumnUid where Id = @moduleEntityId;
 
	-- Step 4. Deleting SysModuleEdit records related to the @moduleEntityId if TypeColumnValue is null
	-- Most probably these records were created during creating of detail from UI.
	delete from SysModuleEdit where SysModuleEntityId = @moduleEntityId and TypeColumnValue is null;
 
	-- Step 5. Inserting a new record to SysModuleEdit to register @pageNameForSpecificType for @typeValue type.
	insert into SysModuleEdit
	(
		CreatedOn, 
		CreatedById, 
		ModifiedOn, 
		ModifiedById, 
		SysModuleEntityId, 
		TypeColumnValue, 
		UseModuleDetails, 
		Position, 
		CardSchemaUId, 
		ActionKindCaption, 
		ActionKindName, 
		PageCaption
	)
	values
	(
		@currentDateTime,
		@userId,
		@currentDateTime,
		@userId,
		@moduleEntityId,
		@typeValue,
		1,
		@itemPosition,
		@cardSchemaUId,
		@actionKindCaption,
		@actionKindName,
		@pageCaption
	);
 
	-- Step 6. Storing just created SysModuleEdit record Id, it's used in next localization steps
	declare @moduleEditRecordId uniqueidentifier = (select top 1 Id from SysModuleEdit where CardSchemaUId = @cardSchemaUId and TypeColumnValue = @typeValue);
 
	-- Step 7. Insert localozation values for [United Kindom] (if such culture exists)
	if (exists (select 1 from SysCulture where Id = @cultureUnitedKindomId))
	begin
		-- Step 7.1. Action kind caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @actionKindCaptionElementId, @cultureUnitedKindomId, @actionKindCaption);
		-- Step 7.2. Card header caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @pageCaptionElementId, @cultureUnitedKindomId, @pageCaption);
	end
 
	-- Step 8. Insert localozation values for [United States] (if such culture exists)
	if (exists (select 1 from SysCulture where Id = @cultureUnitedStatesId))
	begin
		-- Step 8.1. Action kind caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @actionKindCaptionElementId, @cultureUnitedStatesId, @actionKindCaption);
		-- Step 8.2. Card header caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @pageCaptionElementId, @cultureUnitedStatesId, @pageCaption);
	end
END

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE FUNCTION [dbo].[GetColumnUId]
(
        @tableName nvarchar(255)
        ,@columnName nvarchar(255)
)
RETURNS uniqueidentifier
AS
BEGIN
        declare @columnUId uniqueidentifier;
 
        SELECT @columnUId= CONVERT(uniqueidentifier, value)
        FROM sys.extended_properties AS ep
        INNER JOIN sys.TABLES AS t ON ep.major_id = t.object_id
        INNER JOIN sys.COLUMNS AS c ON ep.major_id = c.object_id AND ep.minor_id = c.column_id
        WHERE 
                class = 1
                AND ep.name = 'TS.EntitySchemaColumn.UId'
                AND t.name = @tableName
                AND c.name = @columnName
        ORDER BY t.name;
 
        RETURN @columnUId;
END
GO

USE [bpm-eng]
GO
/****** Object:  StoredProcedure [dbo].[tsp_RegisterDetailPage]    Script Date: 6/4/2015 4:42:41 PM ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[tsp_RegisterDetailPage]
	@detailObjectName nvarchar(255)
	,@typeColumnName nvarchar(255)
	,@typeValue uniqueidentifier
	,@pageNameForSpecificType nvarchar(255)
	,@itemPosition int
	,@actionKindCaption nvarchar(255)
	,@actionKindName nvarchar(255)
	,@pageCaption nvarchar(255)
AS
BEGIN
	SET NOCOUNT ON;
 
	-- Step 1. Declare constants
	declare @cultureUnitedKindomId uniqueidentifier = 'A5420246-0A8E-E111-84A3-00155D054C03';
	declare @cultureUnitedStatesId uniqueidentifier = 'D294EECE-62E7-46DA-ACA3-381D2E825C7D';
	declare @pageCaptionElementId uniqueidentifier = '55132174-2B96-4E0A-830C-B8E952B12C45'; -- TODO: Know from which table and if correct.
	declare @actionKindCaptionElementId uniqueidentifier = 'A19BF4BF-E22B-49B5-B6E0-918FF6290020';
 
	-- Step 2. Initializing variables
	declare @currentDateTime datetime = GETDATE();
	declare @detailObjectUid uniqueidentifier = (select top 1 UId from SysSchema ss where ss.Name = @detailObjectName);
	declare @cardSchemaUId uniqueidentifier = (select top 1 UId from SysSchema where Name = @pageNameForSpecificType);
	declare @userId uniqueidentifier = (select top 1 CreatedById from SysSchema where [UId] = @detailObjectUid);
	declare @typeColumnUid uniqueidentifier = [dbo].[GetColumnUId](@detailObjectName,@typeColumnName);
 
	-- Step 3. Getting SysModuleEntity Id and updating a record with @typeColumnUid
	declare @moduleEntityId uniqueidentifier = (select Id from SysModuleEntity sme where sme.SysEntitySchemaUId = @detailObjectUid);
	if (@moduleEntityId is null)
		begin
			insert into SysModuleEntity(SysEntitySchemaUId, TypeColumnUId) VALUES(@detailObjectUid, @TypeColumnUId);
			set @moduleEntityId = (select top 1 Id from SysModuleEntity where SysEntitySchemaUId = @detailObjectUid);
		end
	else
		update SysModuleEntity set TypeColumnUId = @typeColumnUid where Id = @moduleEntityId;
 
	-- Step 4. Deleting SysModuleEdit records related to the @moduleEntityId if TypeColumnValue is null
	-- Most probably these records were created during creating of detail from UI.
	delete from SysModuleEdit where SysModuleEntityId = @moduleEntityId and TypeColumnValue is null;
 
	-- Step 5. Inserting a new record to SysModuleEdit to register @pageNameForSpecificType for @typeValue type.
	insert into SysModuleEdit
	(
		CreatedOn, 
		CreatedById, 
		ModifiedOn, 
		ModifiedById, 
		SysModuleEntityId, 
		TypeColumnValue, 
		UseModuleDetails, 
		Position, 
		CardSchemaUId, 
		ActionKindCaption, 
		ActionKindName, 
		PageCaption
	)
	values
	(
		@currentDateTime,
		@userId,
		@currentDateTime,
		@userId,
		@moduleEntityId,
		@typeValue,
		1,
		@itemPosition,
		@cardSchemaUId,
		@actionKindCaption,
		@actionKindName,
		@pageCaption
	);
 
	-- Step 6. Storing just created SysModuleEdit record Id, it's used in next localization steps
	declare @moduleEditRecordId uniqueidentifier = (select top 1 Id from SysModuleEdit where CardSchemaUId = @cardSchemaUId and TypeColumnValue = @typeValue);
 
	-- Step 7. Insert localozation values for [United Kindom] (if such culture exists)
	if (exists (select 1 from SysCulture where Id = @cultureUnitedKindomId))
	begin
		-- Step 7.1. Action kind caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @actionKindCaptionElementId, @cultureUnitedKindomId, @actionKindCaption);
		-- Step 7.2. Card header caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @pageCaptionElementId, @cultureUnitedKindomId, @pageCaption);
	end
 
	-- Step 8. Insert localozation values for [United States] (if such culture exists)
	if (exists (select 1 from SysCulture where Id = @cultureUnitedStatesId))
	begin
		-- Step 8.1. Action kind caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @actionKindCaptionElementId, @cultureUnitedStatesId, @actionKindCaption);
		-- Step 8.2. Card header caption
		insert into SysModuleEditLcz (RecordId, ColumnUId, SysCultureId, Value)
		values (@moduleEditRecordId, @pageCaptionElementId, @cultureUnitedStatesId, @pageCaption);
	end
END